|
|
|
Para enviar correo electrónico desde sus páginas ASP, utilice las siguientes instrucciones de programación.
|
<%
Const cdoBasic = 1 'Usar autenticación básica (texto sin cifrar, clear-text).
Const cdoSendUsingPort = 2
'cdosys related
Dim iMsg
Dim iConf
Dim Flds
'mail related
Dim strMsg
Dim strTo
Dim strCC
Dim strFrom
Dim strSubject
Dim strTextBody
'==================inicie su configuración=============================
'debe tener un nombre de usuario y una contraseña o no podrá enviar
'
Dim sendusername : sendusername = "user@userdomain.com"
Dim userpassword : userpassword = "yourpassword"
Dim smtpserver : smtpserver = "yoursmtpserver"
'end your configuration
'===================inicio configurar su info aquí============================
'configure los encabezados TO, CC, From, Subject y también el cuerpo del mensaje aquí
'
strTo = "touser@somedomain.com"
strCC = "anotheruser@somedomain.com"
strFrom = "fromuser@somedomain.com"
strSubject = "Insert here your subject text"
strTextBody = "Insert here your plain body text"
'fin configurar su info aquí
'Crear mensajes y objetos de configuración
set iMsg = CreateObject("CDO.Message")
set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
'Apply settings to the configuration object
With Flds
 ' Especifique el mecanismo de autenticación para la autenticación básica (clear-text, sin cifrar).
.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
' El nombre de usuario para autenticarse ante un servidor SMTP
.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = sendusername
' La contraseña utilizada para autenticarse ante un servidor SMTP
.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = userpassword
' Puerto
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
'Especifique el servidor de correo
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = smtpserver
'Especifique el tiempo de espera en segundos
.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
' El puerto, en el que el servicio SMTP que está especificado en el campo smtpserver, está a la espera de conexiones (típicamente el 25)
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
'Utilizar SSL para la conexión (Verdadero o Falso)
'.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
.Update
End With
'Aplicar la configuración al objeto de mensaje y enviarlo
With iMsg
Set .Configuration = iConf
.To = strTo
.From = strFrom
If strCC <> "" Then
.CC = strCC
End If
.Subject = strSubject
.TextBody = strTextBody
'Enviar mensaje
.Send
End With
' limpieza de objetos de correo
Set iMsg = Nothing
Set iConf = Nothing
Set Flds = Nothing
%>
|
|
|
